Pine Script indikatörleri

VIOP izleme

Niteya VIOP Tracking Indicator aşağıdaki işlemleri yaparak VIOP varlıklarının fiyat hareketlerini takip etmenizi sağlar:

• Bir gün önceki en yüksek (highest) ve en düşük (lowest) değerleri grafiğe yatay bir çizgi olarak ekler.
• Bir gün önceki işlem gününün gündüz ve akşam seanslarını farklı arka plan rengi ile boyar.
• Bulunduğunuz günün gündüz ve akşam seanslarını farklı arka plan rengi ile boyar.
• VIOP varlığının başlangıçtan itibaren aldığı en yüksek (highest) ve en düşük (lowest) değerleri bir tabloda gösterir.

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Niteya
//@version=6
indicator("Niteya BG VIOP Tracking", overlay=true)

get_int(value) => 
    str.replace_all(str.format("{0,number,#,###.##}", value), ",", ".")

get_day_values() => 
    [ta.highest(high, last_bar_index), ta.lowest(low, last_bar_index), high[1], low[1]]

// Getting the highest and lowest value from the previous day and the time value on the daily chart
[highest, lowest, highest_day_before, lowest_day_before] = request.security(syminfo.tickerid, "D", get_day_values(), lookahead=barmerge.lookahead_on)

var line l_pdh = na, var line l_pdl = na
var label hline_label_1 = na, var label hline_label_2 = na

// Time Calculations
one_day_ms = 24 * 60 * 60 * 1000 // Millisecond equivalent of 1 day

// Today's and Yesterday's midnight (00:00) timestamps
today_start = timestamp(year(timenow), month(timenow), dayofmonth(timenow), 0, 0)
yesterday_start = today_start - one_day_ms
// Day Checks according to Bar Time
is_today = time >= today_start and time < today_start + one_day_ms
is_yesterday = time >= yesterday_start and time < today_start

// 19:00 Control
is_after_19 = hour >= 19

// Color Definitions
color_light_pink = color.new(#FFC0CB, 80) // Light Pink
color_dark_pink = color.new(#FF69B4, 70) // Dark Pink
color_light_blue = color.new(#ADD8E6, 80) // Light Blue
color_dark_blue = color.new(#0000FF, 85) // Dark Blue

// Color Selection Logic
var color bg_color = na

if is_today 
    if is_after_19 
        bg_color := color_dark_blue 
    else 
        bg_color := color_light_blue
else if is_yesterday 
    if is_after_19 
        bg_color := color_dark_pink 
    else 
        bg_color := color_light_pink
else 
    bg_color := na

// Paint the Background
bgcolor(bg_color)

if barstate.islastconfirmedhistory 

    l_pdh := line.new(bar_index-1, highest_day_before, bar_index, highest_day_before, extend=extend.both, color=color.green) 
    l_pdl := line.new(bar_index-1, lowest_day_before, bar_index, lowest_day_before, extend=extend.both, color=color.red) 

    hline_label_1 := label.new(bar_index-5, l_pdh.get_y1(), text=str.tostring(highest_day_before, '0.00'), style=label.style_none, textcolor=color.green) 
    hline_label_2 := label.new(bar_index-5, l_pdl.get_y1(), text=str.tostring(lowest_day_before, '0.00'), style=label.style_none, textcolor=color.red) 

    table myTable = table.new(position = position.top_right, columns = 2, rows = 4, bgcolor = color.rgb(60, 60, 60), border_width = 1) 

    table.cell(table_id = myTable, column = 0, row = 0, text = "Lowest (Day)", text_color=color.rgb(236, 236, 236), text_halign=text.align_left) 
    table.cell(table_id = myTable, column = 1, row = 0, text = get_int(lowest), text_color=color.red, text_halign=text.align_right, bgcolor=color.rgb(236, 236, 236)) 
    table.cell(table_id = myTable, column = 0, row = 1, text = "Highest (Day)", text_color=color.rgb(236, 236, 236), text_halign=text.align_left) 
    table.cell(table_id = myTable, column = 1, row = 1, text = get_int(highest), text_color=color.green, text_halign=text.align_right, bgcolor=color.rgb(236, 236, 236)) 

Aşağıda, 02.06.2026 tarihinde XU030DM2026 varlığının 1 dakikalık grafikteki indikatör uygulaması gösterilmektedir: