Pine Script indikatörleri

Anlık veri, anlık hacim verisi ve hacim değerlerini gösterme

Tradingview Platformu'nda işlem yaparken, anlık veriye erişim yetkimize göre hacim verisine erişim farklılık göstermektedir. Bu farklılığı ISCTR hisse senedi üzerinden göstermeye çalışalım:

• Anlık veriye erişim hakkımız varsa, grafikte ISCTR hisse senedini seçtiğimizde, syminfo.tickerid otomatik olarak BISTMIXED:ISCTR değerini alıyor, hacim değeri alamıyoruz.
• Anlık veriye erişim hakkımız yoksa, ISCTR seçince syminfo.tickerid otomatik olarak BIST_DLY:ISCTR değerini alıyor, gecikmeli hacim değeri alıyoruz.
• Ancak, anlık veriye erişim hakkımız var olsa bile, kod içinde request.security komutunu BIST_DLY:ISCTR ile kullandığımızda gecikmeli hacim verisini alabiliyoruz:

  volume_g = request.security("BIST_DLY:" + syminfo.ticker, timeframe.period, volume)

Anlık veriye erişim hakkımız varsa, anlık hacim verisine erişim için ayrı bir paket satın almadığımız takdirde, hacim verisine ulaşılamamaktadır.

• syminfo.ticker : ISCTR
• syminfo.tickerid: BIST_DLY:ISCTR veya BISTMIXED:ISCTR
• BIST_DLY:ISCTR -> Gecikmeli veri
• BISTMIXED:ISCTR -> Anlık veri

Aşağıda kodları yer alan Niteya BG Volume indikatörü ile aşağıdaki değerleri ekranda gösterebiliriz. Anlık veriye erişim hakkımız varsa ve ayrıca anlık hacim verisi paketi satın almamışsak gecikmeli hacim verisi alınır.

• syminfo.ticker
• Anlık veri yetkisi durumu
• Hacim verisi durumu
• Hacim verileri

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Niteya
//@version=6
indicator(title = 'Niteya BG Volume', shorttitle = 'NBGVolume')

volume_dly = request.security('BIST_DLY:' + syminfo.ticker, timeframe.period, volume)
volume_g = na(volume) ? volume_dly : volume 

plot(volume_g, color = close > open ? color.teal : color.red, style = plot.style_columns, title = 'Volume')
plot(ta.sma(volume_g, 20), color = color.blue, title = 'Volume SMA')

if barstate.islast
    var table m_table = table.new(position.top_right, columns=2, rows=4, bgcolor=color.rgb(224, 224, 224), border_width=1, border_color=color.rgb(244, 244, 244), force_overlay = true)
    
    table.cell(m_table, 0, 0, 'syminfo.tickerid', text_color=color.white, text_halign=text.align_left, text_size=size.normal, bgcolor=color.rgb(80, 80, 80))
    table.cell(m_table, 0, 1, 'Anlık veri', text_color=color.white, text_halign=text.align_left, text_size=size.normal, bgcolor=color.rgb(80, 80, 80))
    table.cell(m_table, 0, 2, 'Hacim verisi', text_color=color.white, text_halign=text.align_left, text_size=size.normal, bgcolor=color.rgb(80, 80, 80))
    table.cell(m_table, 0, 3, 'Hacim', text_color=color.white, text_halign=text.align_left, text_size=size.normal, bgcolor=color.rgb(80, 80, 80))
    
    table.cell(m_table, 1, 0, syminfo.tickerid, text_color=color.rgb(60, 60, 60), text_halign=text.align_left, text_size=size.normal)
    table.cell(m_table, 1, 1, str.contains(syminfo.tickerid, "BISTMIXED") ? 'Var' : 'Yok', text_color=str.contains(syminfo.tickerid, "BISTMIXED") ? color.green : color.red, text_halign=text.align_left, text_size=size.normal)
    table.cell(m_table, 1, 2, na(volume) ? 'Yok' : 'Var', text_color=na(volume) ? color.red : color.green, text_halign=text.align_left, text_size=size.normal)
    table.cell(m_table, 1, 3, str.replace_all(str.tostring(volume_g, '#,###'), ',', '.'), text_color=color.rgb(60, 60, 60), text_halign=text.align_left, text_size=size.normal)

Aşağıdaki grafikte indikatör uygulaması gösterilmektedir: